Forum: German Forum

@echo off



REM -----------------------------------------
REM Eine Beschreibung der verwendeten Parameter
REM von xcopy gibt es hier:
REM http://www.microsoft.com/resources/documentation/windows/xp/all/proddocs/en-us/xcopy.mspx?mfr=true
REM ------------------------------------------



REM ---------------------------------------------------
REM Beschreibung der Errorlevels
REM 
REM
REM 0 Die Dateien wurden ohne Fehler kopiert. 
REM 1 Es wurden keine zu kopierenden Dateien gefunden. 
REM 2 Der Benutzer hat xcopy durch Drücken von STRG+C abgebrochen. 
REM 3 Es ist ein Initialisierungsfehler aufgetreten. Es steht nicht genügend 
REM Speicherplatz auf dem Datenträger oder im Arbeitsspeicher zur Verfügung, 
REM Sie haben eine ungültige Laufwerkbezeichnung eingegeben oder eine unzulässige 
REM Syntax in der Befehlszeile verwendet. 
REM
REM 4 Beim Schreiben auf den Datenträger ist ein Fehler aufgetreten.
REM -------------------------------------------------------------




REM ---------------------------------
REM Temporäre Variablen setzen
REM ---------------------------------

set log="c:\logfiles\xcopy.log"
set error="c:\logfiles\xcopy.error.log"
set logpfad="c:\logfiles"
set quelle="c:\Anwendungsdaten"
set ziel=d:\backup



REM --------------------------------------------------
REM Prüfen ob das Verzeichnis existiert
REM in welches die Logfiles geschrieben werden sollen
REM wenn nicht, dann das Verzeichnis erstellen
REM -------------------------------------------------

if not exist %logpfad%\nul md %logpfad%

echo Beginne mit der Verarbeitung...........


REM -------------------------------------------------
REM Prüfen ob Zielverzeichnis existiert
REM wenn nicht, dann erstellen
REM -------------------------------------------------


if not exist %ziel% md %ziel%


REM --------------------------------------------------
REM ... und das Kopieren beginnen
REM --------------------------------------------------


echo Beginne mit dem Backup.........
xcopy %quelle% %ziel% /d /m /s /v /i /f /h /k /o /x /y>>%log% 2>>%error%

REM ----------------------------------------------------------------
REM Wenn ein fehler aufgetreten ist, dann zur jeweiligen Fehlersektion springen
REM ----------------------------------------------------------------

if %errorlevel% equ 4 goto fehlerBeimSchreiben
if %errorlevel% equ 3 goto speicherFehler
if %errorlevel% equ 2 goto abort
if %errorlevel% equ 1 goto nothingToDO
if %errorlevel% equ 0 goto delete




REM ------------------------------------------------------
REM Dateien, die im Quellverzeichnis nicht mehr existieren
REM im Ziel verzeichnis suchen und löschen
REM ------------------------------------------------------

:delete
cd /d %ziel%

for /f "tokens=3* delims=\" %%i in ('dir /b /s') do if not exist %quelle%\%%i del %ziel%\%%i & echo %%i gelöscht
goto end

REM -------------------------------------------------------------
REM Fehlersektion Fehler beim Schreiben
REM --------------------------------------------------------------

:fehlerBeimSchreiben
echo Es ist ein Fehler beim Schreiben der Daten aufgetreten.
goto end

REM -------------------------------------------------------------
REM Fehlersektion Speicherfehler
REM --------------------------------------------------------------

:speicherFehler
echo Es ist ein Initialisierungsfehler aufgetreten. Es steht nicht genügend Speicherplatz auf dem Datenträger oder im 

Arbeitsspeicher zur Verfügung, Sie haben eine ungültige Laufwerkbezeichnung eingegeben oder eine unzulässige Syntax in der 

Befehlszeile verwendet.
goto end

REM -------------------------------------------------------------
REM Fehlersektion Abbruch durch Benutzer
REM --------------------------------------------------------------

:abort
echo Das Programm wurde durch STRG+C manuell abgebrochen.
goto end


REM -------------------------------------------------------------
REM Hinweis Keine zu kopierenden Daten gefunden
REM --------------------------------------------------------------

:nothingToDO
echo Es wurden keine zu kopierenden Daten gefunden.
goto end


REM ----------------------------------------------------
REM Endesektion, hier wird noch das Ausführungsdatum
REM und die Uhrzeit mit ins Log geschrieben
REM -----------------------------------------------------

:end
echo %date% %time% >> %log%
echo "**********************************************************">>%log%
echo "**********************************************************">>%log%
echo "**********************************************************">>%log%
echo "**********************************************************">>%log%
timeout /T 30 /NOBREAK